一、命令格式 FOR 参数 %%变量名 IN (相关文件或命令) DO 执行的命令
参数：FOR有4个参数 /d /l /r /f 它们的作用将在下文给出实例介绍；
4个参数指明了for的操作对象，以上四个参数分别是对目录，列表，递归，文件进行操作。
%%变量名：这个变量名可以是小写a-z或者大写A-Z,他们区分大小写,FOR会把每个读取到的值给它;
IN：是命令的格式,照写就是了； (相关文件或命令) ：FOR要把什么东西读取然后赋值给变量；
do：命令的格式,照写就是了；执行的命令：对每个变量的值要执行什么操作就写在这；
二、参数详细介绍
/D：仅为目录，如果 Set 设置变量，将对与 Set 相匹配的每个目录（而不是指定目录中的文件组）执行指定的 Command。
看下面的例子
@echo off
for /d %%i in (*) do @echo %%i
上述命令的作用：把C盘目录下的全部目录名字打印出来,而文件名字一个也不显示!
在看例子,比如我们要把当前路径下文件夹的名字只有1-3个字母的打出来
@echo off
for /d %%i in (???) do @echo %%i
命令作用：当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了
/D参数只能显示当前目录下的目录名字,这个大家要注意!
/R：递归，进入根目录树 [Drive:]Path，在树的每个目录中执行 for 语句。如果在 /R 后没有指定目录，则认为是当前目录。如果 Set 只是一个句点 (.)，则只枚举目录树。
功能：可以把当前或者你指定路径下的文件名字全部读取,注意是文件名字!
@echo off
for /r c:\ %%i in (*.exe) do @echo %%i
命令的作用：把C盘根目录,和每个目录的子目录下面全部的EXE文件都列出来了,这里的c:\就是目录了。
再看一个：
@echo off
for /r %%i in (*.exe) do @echo %%i
注意：参数不一样了，这个命令前面没加那个C:\；也就是没有指定搜索路径,这样它就会以当前目录为搜索路径。
/L：迭代数值范围，使用迭代变量设置起始值 (Start#)，然后逐步执行一组范围的值，直到该值超过所设置的终止值 (End#)
/L 将通过对 Start# 与 End# 进行比较来执行迭代变量。如果 Start# 小于 End#，就会执行该命令。
如果迭代变量超过 End#，则命令解释程序退出此循环。还可以使用负的 Step# 以递减数值的方式逐步执 行此范围内的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 则生成序列 (5 4 3 2 1)。语法是：
看如下代码：
@echo off
for /l %%i in (1,1,5) do @echo %%i
命令的作用：会打印从1 2 3 4 5 这样5个数字，(1,1,5)这个参数也就是表示从1开始每次加1直到5终止!
再来个例子
@echo off
for /l %%i in (1,1,5) do start cmd
命令作用：打开5个cmd窗口；
… /F ：用法如下：
命令格式：
FOR /F ["options"] %%i IN (file) DO command
FOR /F ["options"] %%i IN ("string") DO command
FOR /F ["options"] %%i IN ('command') DO command
这个可能是最常用的，也是最强的命令，主要用来处理文件和一些命令的输出结果。
file代表一个或多个文件
string 代表字符串
command代表命令
["options"] 可选
file为文件名，按照官方的说法是，for会依次将file中的文件打开，并且在进行到下一个文件之前将每个文件读取到内存，按照每一行分成一个一个的元素，忽略空白的行，看个例子。
假如文件a.txt中有如下内容：
第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
你想显示a.txt中的内容，会用什么命令呢？当然是type，type a.txt
for也可以完成同样的命令：
for /f %%i in (a.txt) do echo %%i
还是先从括号执行，因为含有参数/f,所以for会先打开a.txt，然后读出a.txt里面的所有内容，把它作为一个集合，并且以每一行作为一个元素，所以会产生这样的集合，
"第1行第1列 第1行第2列 第1行第3列"， //第一个元素
"第2行第1列 第2行第2列 第2行第3列"， //第二个元素
"第3行第1列 第3行第2列 第3行第3列"} //第三个元素
集合中只有3个元素，同样用%%i依次代替每个元素，然后执行do后面的命令。
为了加强理解/f的作用，请执行一下两个命令，对比即可明白：
for /f %%i in (a.txt) do echo %%i //这个会显示a.txt里面的内容，因为/f的作用，会读出a.txt中的内容。
for %%i in (a.txt) do echo %%i //而这个只会显示a.txt这个文件的名称，并不会读取其中的内容。
通过上面的学习，我们发现for /f会默认以每一行来作为一个元素，但是如果我们还想把每一行再分解更小的内容，该怎么办呢？不用担心，for命令还为我们提供了更详细的参数，使我们将每一行分为更小的元素成为可能。
它们就是：delims和tokens
delims 用来告诉for每一行应该拿什么作为分隔符，默认的分隔符是空格和tab键
比如，还是上面的文件，我们执行下面的命令：
for /f "delims= " %%i in (a.txt) do echo %%i
显示的结果是：
第1行第1列
第2行第1列
第3行第1列
为什么是这样的呢。因为这里有了delims这个参数，=后面有一个空格，意思是再将每个元素以空格分割，默认是只取分割之后的第一个元素。
但是这样还是有局限的，如果我们想要每一行的第二列元素，那又如何呢？
这时候，tokens跳出来说，我能做到。它的作用就是当你通过delims将每一行分为更小的元素时，由它来控制要取哪一个或哪几个。
还是上面的例子，执行如下命令：
for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i
执行结果：
第1行第2列
第2行第2列
第3行第2列
如果要显示第三列，那就换成tokens=3。
同时tokens支持通配符*，以及限定范围。
如果要显示第二列和第三列，则换成tokens=2,3或tokens=2-3,如果还有更多的则为：tokens=2-10之类的。
此时的命令为：
for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j
怎么多出一个%%j？
这是因为你的tokens后面要取每一行的两列，用%%i来替换第二列，用%%j来替换第三列。并且必须是按照英文字母顺序排列的，%%j不能换成%%k，因为i后面是j
执行结果为：
第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列
对以通配符*，就是把这一行全部或者这一行的剩余部分当作一个元素了。
比如：
for /f "tokens=* delims= " %%i in (a.txt) do echo %%i
执行结果为：
第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
其实就跟for /f %%i in (a.txt) do echo %%i的执行结果是一样的。
再如：
for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j
执行结果为：
第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列
用%%i代替第二列，用%%j代替剩余的所有
最后还有skip合eol，这俩个简单，skip就是要忽略文件的前多少行，而eol用来指定当一行以什么符号开始时，就忽略它。
比如：
for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i
结果为:
第3行第1列 第3行第2列 第3行第3列
用skip来告诉for跳过前两行。
如果不加tokens=*的话，执行结果为：
第3行第1列
不知道怎么回事。
再如，当a.txt内容变成：
.第1行第1列 第1行第2列 第1行第3列
.第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
执行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i结果是：
第3行第1列 第3行第2列 第3行第3列
用eol来告诉for忽略以"."开头的行。
同样也必须加tokens=*，否则只会显示"第3行第1列"
没有评论:
发表评论